PCA9632DP1 I2C 4ch LEDドライバ基板

NXP社の PCA9632DP1を搭載した、I²C 接続の 4ch LED ドライバ基板です。PWM 制御による LED の濃淡も表現できます。

基板には LED も搭載しているので、I²Cバスに繋ぐだけで、4つの LED が滑らかに光ります。またこのLED は、基板を複数並べた場合、等間隔で直線状になります。

詳しい制御の方法は、メーカサイトおよびPCA9632DP1のデータシートを参照してください。

◆ 製品仕様（IC の主な機能）

• 動作電圧 2.3V～5.5V
• 4chの独立した LED ポート
• on/off および256段階（8bit）の PWM 階調制御が可能
• 独立制御／グループ制御が可能
• 基板上に、4つの赤色 LED を搭載
• LED ポートは25mA の吸い込み能力
• 基板には、外部ドライブ用信号ピンを搭載
• インターフェースはI²C
• I²C用プルアップ抵抗用のパターン有り（抵抗は未実装）
  
  

※ 使用時の注意

• I²C アドレスは0xC4（1100 010x）で固定となり変更できません。
• ピンヘッダは各自でご用意いただき、ご利用用途に合わせてはんだ付けしてください。

◆ ピン配置

◆ 基板（表）

◆ 基板（裏）

◆ 資料

• データシート（メーカーサイト）
• 回路図（pdf）
• 基板外形図（pdf）
  

◆サンプルコード(Arduino)

• Sample1
  • 4つのLEDが一斉に点滅します。

#include <Wire.h> //I2C通信用

#define PCA9632_DEV_ID 0x62 //全体制御用のI2Cアドレス
void setup()
{
  pinMode(13, OUTPUT); //debug用
  Wire.begin(); //Arduinoがマスター
  /*起動時の処理*/
  Wire.beginTransmission(PCA9632_DEV_ID);//送信先のアドレスを指定して通信開始
  Wire.write(0x00); //MODE制御用のレジスタ
  Wire.write(B10000001); //デフォルトがSLEEP:ENABLEでB100[1]0001になってるので注意
  Wire.endTransmission(); //通信終了
  delay(500);
}

void loop()
{
  /*点灯*/
  digitalWrite(13, HIGH);        //debug用
  Wire.beginTransmission(PCA9632_DEV_ID);
  Wire.write(0x08);             //LED制御用のレジスタアドレス
  Wire.write(B01010101);        //2bit×4個分の点灯制御//00=消灯//01=強制点灯//10=個別PWM制御もON//11=全体PWM制御もON
  Wire.endTransmission();
  delay(500);

  /*消灯*/
  digitalWrite(13, LOW);
  Wire.beginTransmission(PCA9632_DEV_ID);
  Wire.write(0x08);
  Wire.write(0B00000000);
  Wire.endTransmission();
  delay(500);
}

• Sample2
  • 4つのLEDのうち2個が点滅します。明るさは個別に制御されます。

#include <Wire.h> //I2C通信用

#define PCA9632_DEV_ID 0x62 //全体制御用のI2Cアドレス

void setup()
{
  pinMode(13, OUTPUT); //debug用
  Wire.begin(); //Arduinoがマスター
  /*起動時の処理*/
  sendI2C_single(0x00, B10000001); //MODE1//デフォルトがSLEEP:ENABLEでB100[1]0001になってるので注意
  sendI2C_single(0x01, B00100001); //MODE2//全体PWM制御を点滅モードに設定 DMBLNK=1
  sendI2C_single(0x02, B00001111); //PWM0//暗め(データシートp12式1)
  sendI2C_single(0x03, B11111111); //PWM1//明るめ(p12式1)
  sendI2C_single(0x04, B00001111); //PWM2//暗め(p12式3)
  sendI2C_single(0x05, B11111111); //PWM3//明るめ(p12式3)
  sendI2C_single(0x06, B01111111); //GRPPWM//全体PWMのduty比を1:1に(p13式5)
  sendI2C_single(0x07, B00010111); //GRPFREQ//全体PWMの周期を約1secに(p14式7)
  sendI2C_single(0x08, B11111010); //LEDOUT//3,2,1,0//00=消灯//01=強制点灯//10=個別PWM制御もON//11=全体PWM制御もON
  delay(1);
}

void loop()
{
  /**************  LED3,2は10で個別PWMにより調光されている  LED1,0は11で個別PWMによって調光された上で、点滅モードの全体PWMで点滅している  **************/
}

/*データ送信用簡易関数*/
void sendI2C_single(byte REG, byte DATA)
{
  Wire.beginTransmission(PCA9632_DEV_ID);//送信先のアドレスを指定して書き込み用に通信開始
  Wire.write(REG);//データを書き込むレジスタアドレスを送信
  Wire.write(DATA);//データを送信
  Wire.endTransmission(); //通信終了
}

商品コード: SSCI-023788